Call32 ermöglicht den Aufruf von 32 Bit - Windows-API-Funktionen aus einer Visual Basic 16 Bit - Anwendung heraus

• Das Problem
• Die Lösung
• Der Lösungsweg
• Zu beachten
• Ein Beispiel
• Der Download

• In 16-Bit-VisualBasic-Anwendungen ist es nicht möglich, API-Aufrufe an 32-Bit-dlls zu richten.
• Aufrufe gegen z.B. "kernel32" mißlingen daher in Access-2.0 IMMER.
• Der unterschiedliche Funktionsumfang der kernel-Dateien unter Win9x und Windows NT führt zu weiteren Komplikation:
  So wird z.B. von Access 2.0 aus eine API-Funktion "GetFileAttributes" unter Win9x im "kernel" gefunden, Windows NT meldet aber "Sub oder Function nicht definiert".

nach oben

• kommt von Peter Golde (Author und Verfasser der Ur-Version) und Rob Lichtefeld (Verfasser der verwendeten Version)
• und ermöglicht, aus 16-Bit-VB-Anwendungen heraus beliebige Aufrufe an 32-Bit-dlls zu richten.

nach oben

• Der Modul-Deklarationsbereich muß für die call32-Funktionalitäten 2 Zeilen enthalten:

  Declare Function Declare32 Lib "call32.dll" (ByVal Func As String, ByVal Library As String, ByVal Args As String) As Long
  Declare Sub FreeCall32IDs Lib "call32.dll" ()
  

• Alle 32-Bit-Aufrufe erfolgen immer gegen die Lib "call32.dll" mit dem Alias "Call32", z.B.:

  Declare Function GetFileAttributesA Lib "call32.dll" Alias "Call32" (ByVal lpFileName As String, ByVal lngdAdditionalAufrufId As Long) As Long
  

• Die Aufrufe werden in Prozeduren gefasst, da sie von zusätzlichem Code begleitet werden müssen.
  Das Ganze läuft immer nach folgendem Schema ab:
  • Ein Aufruf gegen declare32 holt mit Nennung von API-Prozedur-, Bibliotheksname und Parametertypen-Ankündigung ("i" 32 bit integer oder handle, "p" pointer type, "w" als 16- oder 32-bit HWND) eine Aufruf-Id als Long ab.

    lngAufrufId = Declare32("GetFileAttributesA", "kernel32", "p")
    

  • Danach der eigentlich erwünschte API-Call mit Nennung der Aufruf-Id als zusätzlichen Parameter:

    lngReturnValue = GetFileAttributesA(sDateiname, lngAufrufId)
    

  • Als letztes erfolgt eine Speicher-aufräumende Anweisung:

    FreeCall32IDs
    

  Innerhalb einer solchen Routine können die Rückgabewerte der angesprochenen API-Funktionen nach Bedarf verarbeitet werden.

nach oben

• Falls man die call32.dll nicht im Windows-Systemverzeichnis, sondern z.B. im Anwendungsverzeichnis unterbringt, muß sichergestellt werden, daß beim Aufruf das aktuelle Arbeitsverzeichnis demjenigen entspricht, in dem sich die call32.dll befindet.

nach oben

• Im 16-Bit-Umfeld half mir eine selbstgeschriebene Funktion Exists_File() die Existenz von Dateien in einem evtl. benannten Verzeichnis zu überprüfen (mittels der rührseligen Dir()-Funktion).
  Spätestens beim exzessiven Einsatz langer Namen (lange Pfadnamen sowie lange Dateinamen) gibt es damit aber massive Probleme, wenn Dir$() auf so Sachen wie tempor~1 stößt und Vergleiche mit dem wirklichen Namen fehlschlagen.
  Deswegen hier als Beispiel für den Einsatz der call32.dll-Funktionalitäten eine moderne Funktion Exists_File32().
  Vorausgesetzt werden im Modul-Deklarationsbereich (wie auch oben beschrieben) folgende 3 Zeilen:

  Declare Function Declare32 Lib "call32.dll" (ByVal Func As String, ByVal Library As String, ByVal Args As String) As Long
  Declare Sub FreeCall32IDs Lib "call32.dll" ()
  
  Declare Function GetFileAttributesA Lib "call32.dll" Alias "Call32" (ByVal lpFileName As String, ByVal lngdAdditionalAufrufId As Long) As Long
  

  Und hier die Funktion Exists_File32(), die auf eine wiederum gekapselte Funktion GetFileAttributesA_Call32() zurückgreift:

  Function Exists_File32 (sFile As String) As Integer
  
      On Error GoTo err_Exists_File32
  
      ' **** Beherrscht dank call32 langen Pfad- wie auch Dateinamen. ****
  
      Dim iRet As Integer
  
      If GetFileAttributesA_Call32(sFile) > 0 Then
         iRet = True
      End If
  
      Exists_File32 = iRet
  
      Exit Function
  
  
  err_Exists_File32:
  
      Fehler "Exists_File32"
      Exit Function
  
  End Function
  

  Das stützt sich leicht mißbrauchend auf die 32-Bit-API-Funktion GetFileAttributes:

  Function GetFileAttributesA_Call32 (sFile As String) As Long
  
      On Error GoTo err_GetFileAttributesA_Call32
  
      Dim lngAufrufId As Long
  
      lngAufrufId = Declare32("GetFileAttributesA", "kernel32", "p")
  
      ' ****  Alle erforderlichen sowie die call32-Aufruf-Id als zusätzlichen Parameter ****
  
      GetFileAttributesA_Call32 = GetFileAttributesA(sFile, lngAufrufId)
  
  
  exit_GetFileAttributesA_Call32:
  
      FreeCall32IDs   ' DLL-Aufruf-Speicher aufräumen
  
      Exit Function
  
  
  err_GetFileAttributesA_Call32:
  
      Fehler "GetFileAttributesA_Call32"
  
      If Err = 53 Then    ' evtl. entspricht das aktuelle Arbeitsverzeichnis
        Beep              ' nicht dem Anwendungs-Verzeichnis, z.B. bei manuellem Start.
        MsgBox "Bitte starten Sie die Anwendung auf die dafür vorgesehene Weise.", 64, "GetFileAttributesA_Call32"
        Exit Function
      End If
  
      Resume exit_GetFileAttributesA_Call32
  
  End Function
  

nach oben

• call32v2.zip (44kB): Die gepackten Dateien im Original-Umfang.

nach oben

  xhtml1.0